*
* KUMAC pour demontrer la methode de coupures en une dimension
*                                      MP 5/95
opt nsta
opt fit
set fit 111111
his/cre/1d  100 'Echantillon mixte 2 classes' 50 0. 1.5
his/cre/1d  101 'Probabilite de meclassification ' 15 0. 1.5
his/cre/1d  102 'Probabilite de meclassification a' 15 0. 1.5
his/cre/1d  103 'Probabilite de meclassification b' 15 0. 1.5
*                                Creation echantillon mixte 2 classes
sigma na=7500 ;   sigma nb=2500
sigma  a=.4   ;   sigma da=.15
sigma  b=.85  ;   sigma db=.075
sigma r1=rndm(array(na)) ; sigma r2=rndm(array(na))
sigma fa=sin(2.*pi*r1)*sqrt(-2.*log(r2))*da + a
sigma r1=rndm(array(nb)) ; sigma r2=rndm(array(nb))
sigma fb=cos(2.*pi*r1)*sqrt(-2.*log(r2))*db + b
*
zone 1 2
vec/hfill fa 100
vec/hfill fb 100
vec/cre par(6) r 300. .4 .1 600. .85 .15
his/fit 100 g+g ' ' 6 par
*                                 Probabilite de fausse classification
sigma fa=order(fa,fa)
sigma fb=order(fb,fb)
i=0
vec/cre pma(16) r ; vec/cre pmb(16) r
vec/cre pmac(1) r ; vec/cre pmbc(1) r
do c=0.0,1.5,0.1
   sigma aa= fa lt [c]  ;   sigma naa= vsum(aa)
   sigma bb= fb lt [c]  ;   sigma nbb= vsum(bb)
   sigma pmac= (na-naa)/na
   sigma pmbc= nbb/nb
   i=[i]+1
   vec/copy pmac(1:1) pma([i]:[i])
   vec/copy pmbc(1:1) pmb([i]:[i])
enddo
his/put/cont 102 pma
his/put/cont 103 pmb
his/op/add 102 103 101
his/plot 101 'c'
his/plot 102 'cs'
his/plot 103 'cs'