* Nom du fichier: grb.kumac
*
* KUMAC pour demontre la methode des side-bands
*                                      MP 04/01
*              Sauvegarde du graphique sur fichier ps
* Gaussienne pour mu(n)=216 et mu(b)=9.8
ne = 50000
*                                         variance   esperance
*                                            v           v
sigma r1=rndm(array([ne]))
sigma r2=rndm(array([ne]))
sigma ns=sin(2.*3.14159*r1)*sqrt(-2.*log(r2))*sqrt(157.2) + 157.2
sigma nb=cos(2.*3.14159*r1)*sqrt(-2.*log(r2))*sqrt(58.8)  +  58.8
sigma r3=rndm(array([ne]))
sigma r4=rndm(array([ne]))
sigma nsb=(sin(2.*3.14159*r3)*sqrt(-2.*log(r4))*sqrt(588) + 588)*0.1
sigma n=ns+nb 
sigma no=n-nsb
* 
 his/cre/2d 10 'Distribution ns vs nb'     50 0. 100. 50 100. 300. 
 his/cre/proy 10
 his/cre/2d 11 'Distribution n  vs nb'     50 0. 100. 50 100. 300.
 his/cre/proy 11
 his/cre/2d 12 'Distribution n-nsb vs nsb' 50 0. 100. 50 100. 300.
 his/cre/proy 12
 do i=1,[ne]
    call hfill(10,nb([i]),ns([i]),1.)
    call hfill(11,nb([i]),n([i]),1.)    
    call hfill(12,nsb([i]),no([i]),1.)    
enddo
*                        Presentation
 zone 1 1
 opt nsta
 opt utit
 his/plo 10
 atit 'nb' 'ns'
 pic/pri grb1.eps
 wait
 his/plo 11
 atit 'nb' 'n'
 pic/pri grb2.eps
 wait
 his/plo 12
 atit 'nsb' 'n-nsb'
 pic/pri grb3.eps
 wait
 opt stat
 zone 1 3
 his/plo 10.proy
 atit 'ns'
 his/plo 11.proy 
 atit 'n'
 his/plo 12.proy 
 atit 'n-nsb'
 pic/pri grb4.eps